blob: 9d05c80d263bc64da21e794ddd00a2ce90d9c497 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
/* scanner generator for flashmap descriptor language */
/* SPDX-License-Identifier: GPL-2.0-only */
%{
#include "fmd_parser.h"
#include <assert.h>
#include <string.h>
int parse_integer(char *src, int base);
int copy_string(const char *src);
%}
%option noyywrap
%s FLAGS
MULTIPLIER [KMG]
%%
[[:space:]]+ /* Eat whitespace. */
#.*$ /* Eat comments. */
\( BEGIN(FLAGS); return *yytext;
<FLAGS>\) BEGIN(INITIAL); return *yytext;
<FLAGS>CBFS return FLAG_CBFS;
<FLAGS>PRESERVE return FLAG_PRESERVE;
0{MULTIPLIER}? |
[1-9][0-9]*{MULTIPLIER}? return parse_integer(yytext, 10);
0[0-9]+{MULTIPLIER}? return OCTAL;
0[xX][0-9a-fA-F]+{MULTIPLIER}? return parse_integer(yytext + 2, 16);
[^#@{}()[:space:]]* return copy_string(yytext);
. return *yytext;
%%
int parse_integer(char *src, int base)
{
char *multiplier = NULL;
unsigned val = strtoul(src, &multiplier, base);
if (*multiplier) {
switch(*multiplier) {
case 'K':
val *= 1024;
break;
case 'M':
val *= 1024*1024;
break;
case 'G':
val *= 1024*1024*1024;
break;
default:
// If we ever get here, the MULTIPLIER regex is allowing
// multiplier suffixes not handled by this code.
assert(false);
}
}
yylval.intval = val;
return INTEGER;
}
int copy_string(const char *src)
{
yylval.strval = strdup(src);
return STRING;
}
|
