pcengines/apu1: Add ACPI led, button and GPIO devices.

Provide ACPI devices with devicetree-compatible annotations for the
three leds and the button of the APU1, as well as the GPIO driver.

This will cause the Linux kernel to automatically load the following
modules:
  leds_gpio (CONFIG_LEDS_GPIO)
  gpio_keys_polled (CONFIG_KEYBOARD_GPIO_POLLED)
  gpio_sb8xx (CONFIG_GPIO_SB8XX)

See
http://events.linuxfoundation.org/sites/events/files/slides/ACPI_vs_DT.pdf
and https://lwn.net/Articles/612062/ for some more information on how
the PRP0001 HID works.

To make this usable a Linux GPIO driver for the AMD chipset is also
required, which I am currently working on, but have not submitted
upstream yet.

Leds have been named after the convention in
Documentation/leds/leds-class.txt:
LED Device Naming
=================
Is currently of the form:
"devicename:colour:function"

For comparison, on an OpenWRT device:
GPIOs 0-21, ath79:
 gpio-1   (tp-link:green:usb   ) out hi
 gpio-2   (tp-link:green:system) out lo
 gpio-3   (reset               ) in  hi
 gpio-5   (tp-link:green:qss   ) out lo
 gpio-7   (qss                 ) in  hi
 gpio-9   (tp-link:green:wlan  ) out lo
 gpio-18  (rtl8366rb           ) in  hi
 gpio-19  (rtl8366rb           ) in  hi

On the apu1:
GPIOs 288-511, platform/PRP0001:00, AMD SB8XX/SB9XX/A5X/A8X GPIO driver:
 gpio-475 (switch1             ) in  hi
 gpio-477 (apu1:green:led1     ) out hi
 gpio-478 (apu1:green:led2     ) out hi
 gpio-479 (apu1:green:led3     ) out hi

Change-Id: I956ee92d9d98ef27a83ccb30d314543bd8634f2c
Signed-off-by: Tobias Diedrich <ranma+coreboot@tdiedrich.de>
Reviewed-on: http://review.coreboot.org/10540
Tested-by: build bot (Jenkins)
Reviewed-by: Paul Menzel <paulepanter@users.sourceforge.net>
Reviewed-by: Kyösti Mälkki <kyosti.malkki@gmail.com>

4 files changed, 183 insertions, 0 deletions

diff --git a/src/mainboard/pcengines/apu1/acpi/buttons.asl b/src/mainboard/pcengines/apu1/acpi/buttons.asl
new file mode 100644
index 0000000000..e7c3165f38
--- /dev/null
+++ b/src/mainboard/pcengines/apu1/acpi/buttons.asl
@@ -0,0 +1,57 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Based on the example of Mika Westerberg: https://lwn.net/Articles/612062/
+ *
+ * Copyright (C) 2015 Tobias Diedrich, Mika Westerberg
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc.
+ */
+
+Scope (\_SB.PCI0.SBUS)
+{
+	Device (BTNS)
+	{
+		Name (_HID, "PRP0001")
+
+		Name (_CRS, ResourceTemplate () {
+			GpioIo (Exclusive, PullUp, 0, 0, IoRestrictionInputOnly,
+				"\\_SB.PCI0.SBUS.GPIO", 0, ResourceConsumer) {187}
+		})
+
+		Name (_DSD, Package () {
+			ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+			Package () {
+				Package () {"compatible", Package () {"gpio-keys-polled"}},
+				Package () {"poll-interval", 100},
+				Package () {"autorepeat", 1}
+			}
+		})
+
+		Device (BTN1)
+		{
+			Name (_DSD, Package () {
+				ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+				Package () {
+					/* BTN_1 is 0x101 in linux/input.h */
+					Package () {"linux,code", 257},
+					Package () {"linux,input-type", 1},
+					/* labeled S1 on the board, MODESW in the gpio header files */
+					Package () {"label", "switch1"},
+					Package () {"gpios", Package () {^^BTNS, 0, 0, 1 /* low-active */}},
+				}
+			})
+		}
+	}
+}
diff --git a/src/mainboard/pcengines/apu1/acpi/gpio.asl b/src/mainboard/pcengines/apu1/acpi/gpio.asl
new file mode 100644
index 0000000000..50fe7e1a14
--- /dev/null
+++ b/src/mainboard/pcengines/apu1/acpi/gpio.asl
@@ -0,0 +1,40 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Based on the example of Mika Westerberg: https://lwn.net/Articles/612062/
+ *
+ * Copyright (C) 2015 Tobias Diedrich, Mika Westerberg
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc.
+ */
+
+Scope (\_SB.PCI0.SBUS)
+{
+	Device (GPIO)
+	{
+		Name (_HID, "PRP0001")
+
+		Name (_CRS, ResourceTemplate () {
+			/* ACPI_MMIO_BASE + gpio offset */
+			Memory32Fixed(ReadWrite, 0xFED80100, 0x0000100)
+		})
+
+		Name (_DSD, Package () {
+			ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+			Package () {
+				Package () {"compatible", Package () {"gpio-sb8xx"}},
+			}
+		})
+	}
+}
diff --git a/src/mainboard/pcengines/apu1/acpi/leds.asl b/src/mainboard/pcengines/apu1/acpi/leds.asl
new file mode 100644
index 0000000000..ce4a0c878b
--- /dev/null
+++ b/src/mainboard/pcengines/apu1/acpi/leds.asl
@@ -0,0 +1,80 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Based on the example of Mika Westerberg: https://lwn.net/Articles/612062/
+ *
+ * Copyright (C) 2015 Tobias Diedrich, Mika Westerberg
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc.
+ */
+
+Scope (\_SB.PCI0.SBUS)
+{
+	Device (LEDS)
+	{
+		Name (_HID, "PRP0001")
+
+		Name (_CRS, ResourceTemplate () {
+			GpioIo (Exclusive, PullUp, 0, 0, IoRestrictionOutputOnly,
+				"\\_SB.PCI0.SBUS.GPIO", 0, ResourceConsumer) {189, 190, 191}
+		})
+
+		Name (_DSD, Package () {
+			ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+			Package () {
+				Package () {"compatible", Package () {"gpio-leds"}},
+			}
+		})
+
+		Device (LED1)
+		{
+			Name (_DSD, Package () {
+				ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+				Package () {
+					/*
+					 * From Linux Documentation/leds/leds-class.txt:
+					 * LED Device Naming
+					 * Is currently of the form:
+					 * "devicename:colour:function"
+					 */
+					Package () {"label", "apu1:green:led1"},
+					Package () {"gpios", Package () {^^LEDS, 0, 0, 1 /* low-active */}},
+					Package () {"default-state", "keep"},
+				} }) }
+
+		Device (LED2)
+		{
+			Name (_DSD, Package () {
+				ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+				Package () {
+					Package () {"label", "apu1:green:led2"},
+					Package () {"gpios", Package () {^^LEDS, 0, 1, 1 /* low-active */}},
+					Package () {"default-state", "keep"},
+				}
+			})
+		}
+
+		Device (LED3)
+		{
+			Name (_DSD, Package () {
+				ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
+				Package () {
+					Package () {"label", "apu1:green:led3"},
+					Package () {"gpios", Package () {^^LEDS, 0, 2, 1 /* low-active */}},
+					Package () {"default-state", "keep"},
+				}
+			})
+		}
+	}
+}
diff --git a/src/mainboard/pcengines/apu1/dsdt.asl b/src/mainboard/pcengines/apu1/dsdt.asl
index 799f1fdeac..d550c86159 100644
--- a/src/mainboard/pcengines/apu1/dsdt.asl
+++ b/src/mainboard/pcengines/apu1/dsdt.asl
@@ -64,6 +64,12 @@ DefinitionBlock (
 	#include "acpi/sleep.asl"
 
 	#include "acpi/gpe.asl"
+
+	/* Contains the GPIO led and button setup for this board */
+	#include "acpi/buttons.asl"
+	#include "acpi/gpio.asl"
+	#include "acpi/leds.asl"
+
 	#include "acpi/thermal.asl"
 }
 /* End of ASL file */