From dd2bc3f819ecb64a07f37c2a63621ecadd6b6ed8 Mon Sep 17 00:00:00 2001
From: Vladimir Serbinenko <phcoder@gmail.com>
Date: Fri, 31 Oct 2014 09:16:31 +0100
Subject: igd.asl rewrite

Old igd.asl had inconsistent addresses (between _DOD and actual device)
and ghost devices. Any of those is enough to make brightness on windows
fail and make igd.asl out-of-ACPI-spec. Also old code favoured ridiculous
copying of the same thing 6 times per chipset. Leave only hooking up and
chipset-specific part in chipset directory. Move NVS handling and ACPI-spec
parts to a common file.

Change-Id: I556769e5e28b83e7465e3db689e26c8c0ab44757
Signed-off-by: Vladimir Serbinenko <phcoder@gmail.com>
Reviewed-on: http://review.coreboot.org/7472
Tested-by: build bot (Jenkins)
Reviewed-by: Edward O'Callaghan <edward.ocallaghan@koparo.com>
Reviewed-by: Timothy Pearson <tpearson@raptorengineeringinc.com>
---
 src/drivers/intel/gma/igd.asl | 113 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 113 insertions(+)
 create mode 100644 src/drivers/intel/gma/igd.asl

(limited to 'src/drivers/intel/gma/igd.asl')

diff --git a/src/drivers/intel/gma/igd.asl b/src/drivers/intel/gma/igd.asl
new file mode 100644
index 0000000000..31e8fecbd0
--- /dev/null
+++ b/src/drivers/intel/gma/igd.asl
@@ -0,0 +1,113 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (C) 2007-2009 coresystems GmbH
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+ * MA 02110-1301 USA
+ */
+
+	External(LCD0, DeviceObj)
+
+	Name (BRCT, 0)
+
+	Method(BRID, 1, NotSerialized)
+	{
+		Store (Match (BRIG, MEQ, Arg0, MTR, Zero, 2), Local0)
+		If (LEqual (Local0, Ones))
+		{
+			Return (Subtract(SizeOf(BRIG), One))
+		}
+		Return (Local0)
+	}
+
+	Method (XBCL, 0, NotSerialized)
+	{
+		Store (1, BRCT)
+		Return (BRIG)
+	}
+
+	/* Display Output Switching */
+	Method (_DOS, 1)
+	{
+		/* Windows 2000 and Windows XP call _DOS to enable/disable
+		 * Display Output Switching during init and while a switch
+		 * is already active
+		 */
+		Store (And(Arg0, 7), DSEN)
+	}
+
+	/* Using Notify is the right way. But Windows doesn't handle
+	   it well. So use both method in a way to avoid double action.
+	 */
+	Method (DECB, 0, NotSerialized)
+	{
+		If (BRCT)
+		{
+			Notify (LCD0, 0x87)
+		} Else {
+			Store (BRID (XBQC ()), Local0)
+			If (LNotEqual (Local0, 2))
+			{
+				Decrement (Local0)
+			}
+			XBCM (DerefOf (Index (BRIG, Local0)))
+		}
+	}
+
+	Method (INCB, 0, NotSerialized)
+	{
+		If (BRCT)
+		{
+			Notify (LCD0, 0x86)
+		} Else {
+			Store (BRID (XBQC ()), Local0)
+			If (LNotEqual (Local0, Subtract(SizeOf(BRIG), One)))
+			{
+				Increment (Local0)
+			}
+			XBCM (DerefOf (Index (BRIG, Local0)))
+		}
+	}
+
+	/* Device Current Status */
+	Method(XDCS, 1)
+	{
+		TRAP(1)
+		If (And(CSTE, ShiftLeft (1, Arg0))) {
+			Return (0x1f)
+		}
+		Return(0x1d)
+	}
+
+	/* Query Device Graphics State */
+	Method(XDGS, 1)
+	{
+		If (And(NSTE, ShiftLeft (1, Arg0))) {
+			Return(1)
+		}
+		Return(0)
+	}
+
+	/* Device Set State */
+	Method(XDSS, 2)
+	{
+		/* If Parameter Arg0 is (1 << 31) | (1 << 30), the
+		 * display switch was completed
+		 */
+		If (LEqual(And(Arg0, 0xc0000000), 0xc0000000)) {
+			Store (NSTE, CSTE)
+		}
+	}
-- 
cgit v1.2.3